ModelicaAdditions.PetriNets

Information

The PetriNets library allows to model discrete components by a special kind of Petri nets with at most one token on a place, as well as by state transition diagrams (which are special kinds of Petri nets). Petri nets and state transition diagrams are "higher level" constructs for the description of switching elements, parallel activities or syncronization. For several kinds of applications it is much easier and clearer to use these components instead of modeling the discrete behaviour directly with the basic language constructs of Modelica ("if" or "when" statements). A typical Petri net is shown in the following figure:

A Petri net is defined in the following way:

1. It consists of a set of places and of a set of transitions. The places are split into start places which are "active" at the start of the simulation and of "normal" places which are "non-active" at the beginning.
2. Places are connected by transitions, whereby no places and no transitions are directly connected (i.e., a place is connected to a transition which in turn is connected to another place). Any number of start places can be present.
3. An "active" place is characterized by a "token" placed on the place. In the ModelicaAdditions.PetriNets libray a place is "active" when the public variable "state" of the place is true.
4. There are several transition elements in the library. Whenever the states of all inputs to the transition elements are active and when the condition of the transition is true then the following actions are performed:
   • all input states are marked as "inactive", i.e., the token is removed.
   • all output states are marked as "active", i.e., they are marked by new tokens.
   The conditionPort connector of a transition element is used to signal via a Boolean signal whether the condition of a transition is true or false. Alternatively, the condition can be provided as an equation to set the public variable condition of the corresponding transition element.
5. There are several place components in this library (such as Place01, Place10, Place11) which have different number of input and output transition connectors. This is due to the current limitations of the annotations of Modelica, which do not allow to define the graphical location of the elements of a vector of (transition) connectors with unknown length.
6. If two or more transitions of a place would fire at the same time instant, priorities are used in order that exactly one of them fires. The highest priority has a transition connector of a place with the lowest index (e.g. outTransition1 has a higher priority as outTransition2).

The method used in this library to realize Petri nets in Modelica is described in detail in:

Mosterman P.J., Otter M. and Elmqvist H. (1998):

Modeling Petri-Nets as Local Constraint Equations for Hybrid Systems using Modelica. 1998 Summer Computer Simulation Conference (SCSC'98), Reno, U.S.A., 19.-20. Juli (download from here).

This package is not part of the Modelica standard library, because it is planned to realize a package with only one place and one transition component, once vector connectors with unknown length have better support in Modelica.

Main Author:

Martin Otter
Deutsches Zentrum für Luft und Raumfahrt e.V. (DLR)
Institut für Robotik und Mechatronik
Postfach 1116
D-82230 Wessling
Germany
email: Martin.Otter@dlr.de

Release Notes:

• June 12, 2000 by Martin Otter:
  Realized.

Copyright (C) 2000, DLR.

The ModelicaAdditions.PetriNets package is free software; it can be redistributed and/or modified under the terms of the Modelica license, see the license conditions and the accompanying disclaimer in the documentation of package Modelica in file "Modelica/package.mo".

ModelicaAdditions.PetriNets.Place01

Parameters

Name	Default	Description
initialState	false	Initial value of state

Modelica definition

model Place01 "Place with one output transition" 
  parameter Boolean initialState=false "Initial value of state";
  Boolean state(final start=initialState) "State of place";
protected 
  Boolean newState(final start=initialState);
public 
  PetriNets.Interfaces.FirePortOut outTransition;
equation 
  // Set new state for next iteration
  state = pre(newState);
  newState = state and not outTransition.fire;
  
  // Report state to output transition
  outTransition.state = state;
end Place01;

ModelicaAdditions.PetriNets.Place10

Parameters

Name	Default	Description
initialState	false	Initial value of state

Modelica definition

model Place10 "Place with one input transition" 
  parameter Boolean initialState=false "Initial value of state";
  Boolean state(final start=initialState) "State of place";
protected 
  Boolean newState(final start=initialState);
public 
  PetriNets.Interfaces.SetPortIn inTransition;
equation 
  // Set new state for next iteration
  state = pre(newState);
  newState = inTransition.set or state;
  
  // Report state to input transition
  inTransition.state = state;
end Place10;

ModelicaAdditions.PetriNets.Place11

Parameters

Name	Default	Description
initialState	false	Initial value of state

Modelica definition

model Place11 "Place with one input and one output transition" 
  parameter Boolean initialState=false "Initial value of state";
  Boolean state(final start=initialState) "State of place";
protected 
  Boolean newState(final start=initialState);
public 
  PetriNets.Interfaces.SetPortIn inTransition;
  PetriNets.Interfaces.FirePortOut outTransition;
equation 
  // Set new state for next iteration
  state = pre(newState);
  newState = inTransition.set or state and not outTransition.fire;
  
  // Report state to input and output transitions
  inTransition.state = state;
  outTransition.state = state;
end Place11;

ModelicaAdditions.PetriNets.Place21

Parameters

Name	Default	Description
initialState	false	Initial value of state

Modelica definition

model Place21 "Place with two input and one output transition" 
  parameter Boolean initialState=false "Initial value of state";
  Boolean state(final start=initialState) "State of place";
protected 
  Boolean newState(final start=initialState);
public 
  PetriNets.Interfaces.FirePortOut outTransition;
  PetriNets.Interfaces.SetPortIn inTransition1;
  PetriNets.Interfaces.SetPortIn inTransition2;
equation 
  // Set new state for next iteration
  state = pre(newState);
  newState = inTransition1.set or inTransition2.set or state and not 
    outTransition.fire;
  
  // Report state to input and output transitions
  inTransition1.state = state;
  inTransition2.state = inTransition1.state or inTransition1.set;
  outTransition.state = state;
end Place21;

ModelicaAdditions.PetriNets.Place12

Parameters

Name	Default	Description
initialState	false	Initial value of state

Modelica definition

model Place12 "Place with one input and two output transitions" 
  parameter Boolean initialState=false "Initial value of state";
  Boolean state(final start=initialState) "State of place";
protected 
  Boolean newState(final start=initialState);
public 
  PetriNets.Interfaces.SetPortIn inTransition;
  PetriNets.Interfaces.FirePortOut outTransition1;
  PetriNets.Interfaces.FirePortOut outTransition2;
equation 
  // Set new state for next iteration
  state = pre(newState);
  newState = inTransition.set or state and not (outTransition1.fire or 
    outTransition2.fire);
  
  // Report state to input and output transitions
  inTransition.state = state;
  outTransition1.state = state;
  outTransition2.state = outTransition1.state and not outTransition1.fire;
end Place12;

ModelicaAdditions.PetriNets.Place22

Parameters

Name	Default	Description
initialState	false	Initial value of state

Modelica definition

model Place22 "Place with two input and two output transitions" 
  parameter Boolean initialState=false "Initial value of state";
  Boolean state(final start=initialState) "State of place";
protected 
  Boolean newState(final start=initialState);
public 
  PetriNets.Interfaces.FirePortOut outTransition1;
  PetriNets.Interfaces.FirePortOut outTransition2;
  PetriNets.Interfaces.SetPortIn inTransition1;
  PetriNets.Interfaces.SetPortIn inTransition2;
equation 
  // Set new state for next iteration
  state = pre(newState);
  newState = inTransition1.set or inTransition2.set or state and not (
    outTransition1.fire or outTransition2.fire);
  
  // Report state to input and output transitions
  inTransition1.state = state;
  inTransition2.state = inTransition1.state or inTransition1.set;
  outTransition1.state = state;
  outTransition2.state = outTransition1.state and not outTransition1.fire;
end Place22;

ModelicaAdditions.PetriNets.Transition

Parameters

Name	Default	Description
condLabel	" "	Condition as string (e.g. "x > 0")

Modelica definition

model Transition 
  "Transition with one input and one output connection" 
  parameter String condLabel=" " 
    "Condition as string (e.g. \"x > 0\")";
  Boolean condition;
  Boolean fire;
  PetriNets.Interfaces.FirePortIn inTransition;
  PetriNets.Interfaces.SetPortOut outTransition;
  Modelica.Blocks.Interfaces.BooleanInPort conditionPort(final n=1);
equation 
  condition = conditionPort.signal[1];
  fire = condition and inTransition.state and not outTransition.state;
  inTransition.fire = fire;
  outTransition.set = fire;
end Transition;

ModelicaAdditions.PetriNets.Parallel

Parameters

Name	Default	Description
condLabel	" "	Condition as string (e.g. "x > 0")

Modelica definition

model Parallel "Transition with one input and two output connections"
   
  parameter String condLabel=" " 
    "Condition as string (e.g. \"x > 0\")";
  Boolean fire;
  Boolean condition;
  PetriNets.Interfaces.FirePortIn inTransition;
  PetriNets.Interfaces.SetPortOut outTransition1;
  PetriNets.Interfaces.SetPortOut outTransition2;
  Modelica.Blocks.Interfaces.BooleanInPort conditionPort(final n=1);
equation 
  condition = conditionPort.signal[1];
  fire = condition and inTransition.state and not (outTransition1.state or 
    outTransition2.state);
  inTransition.fire = fire;
  outTransition1.set = fire;
  outTransition2.set = fire;
end Parallel;

ModelicaAdditions.PetriNets.Synchronize

Parameters

Name	Default	Description
condLabel	" "	Condition as string (e.g. "x > 0")

Modelica definition

model Synchronize 
  "Transition with two input and one output connections" 
  parameter String condLabel=" " 
    "Condition as string (e.g. \"x > 0\")";
  Boolean condition;
  Boolean fire;
  PetriNets.Interfaces.FirePortIn inTransition1;
  PetriNets.Interfaces.FirePortIn inTransition2;
  PetriNets.Interfaces.SetPortOut outTransition;
  Modelica.Blocks.Interfaces.BooleanInPort conditionPort(final n=1);
equation 
  condition = conditionPort.signal[1];
  fire = condition and inTransition1.state and inTransition2.state and not 
    outTransition.state;
  inTransition1.fire = fire;
  inTransition2.fire = fire;
  outTransition.set = fire;
end Synchronize;