HyLibLight.Examples

Information

This package contains demo models to demonstrate the usage of the
HyLibLight package. Open the models and simulate them according to the 
provided description in the models.

The following demo models are present:

   ClosedCircuit  Drive system with a closed circuit
   OpenCircuit    Drive system with an open circuit
   SecControl     Secondary control of hydrostatic transmission

Release Notes:
--------------

1999 - 10 - 9:	coded

HyLibLight.Examples.ClosedCircuit

Information

This model describes the dynamic behaviour of an closed circuit hydraulic drive.
Open circuit means that the pump flow goes direct to the motor and the return
flow from the motor in a closed circuit direct to the pump, not to the tank.


The vehicle is powered by a Diesel engine that is modelled by the torque 
characterisitics. At the beginning of the simulation the engine is running 
(i. e. initial condition w = 240 rad/sec) and for 1 second the charge pumps
build up the pressure. Then the main pump gets the signal to pump oil to the 
motor according to the sinusoidal signal from the signal generator. This means
the driver is changing rapidly from going forward to going backward. As a
consequence the hydro motor changes the direction of rotation.

When looking at the pressure curves the effects of the relief valve can be
seen clearly. The high pressure doesn't exceed 420 bar.

The speed of the Diesel engine is changing according to the demands of
the hydraulic system. If the vehicle is to be accelerated the speed drops,
if it is to be decelerated the speed goes up.

Release Notes:
--------------
1999 - 10 - 9:	coded

Modelica definition

model ClosedCircuit "Drive system with a closed circuit" 
  extends Modelica.Icons;
  HyLibLight.Pumps.Diesel Diesel(J=1.3);
  HyLibLight.Pumps.VarPump HPV(
    Dpump=0.09e-3, 
    GPint=5e-12, 
    GPext=0.4e-12, 
    J=0.1, 
    volumeA=2.5e-5, 
    volumeB=2.5e-5);
  HyLibLight.Pumps.ConPump CP(
    Dpump=0.02e-3, 
    GPint=4e-13, 
    GPext=1e-13, 
    J=0.1, 
    volumeA=0.5e-3, 
    volumeB=0.5e-3) "charge pump";
  HyLibLight.Pumps.Tank T(ppreload=5e4);
  HyLibLight.Pumps.ConMot HMF(
    Dmotor=0.09e-3, 
    GMext=0.4e-12, 
    GMint=5e-12, 
    J=4, 
    volumeA=2.5e-5, 
    volumeB=2.5e-5);
  HyLibLight.Components.ReliefValve RelCP(
    pclosed=16e5, 
    popen=17e5, 
    volumeA=0.5e-3, 
    volumeB=0.5e-3) "Relief valve for high charge pump";
  HyLibLight.Pumps.Tank T1;
  HyLibLight.Components.ReliefValve RelHP2(
    pclosed=400e5, 
    popen=405e5, 
    volumeA=2.5e-5, 
    volumeB=2.5e-5) "Relief valve for high pressure circuit";
  HyLibLight.Components.ReliefValve RelHP1(
    pclosed=400e5, 
    popen=405e5, 
    volumeA=2.5e-5, 
    volumeB=2.5e-5) "Relief valve for high pressure circuit";
  Modelica.Blocks.Sources.Sine SinWave(freqHz={0.15}, startTime={1.0}) 
    "command signal for drive pump";
  Modelica.Blocks.Sources.Constant Constant 
    "command signal for Diesel engine";
  HyLibLight.Components.CheckValve ChV2(
    pclosed=1e5, 
    popen=1.25e5, 
    diameter=10e-3, 
    volumeA=2.5e-5, 
    volumeB=2.5e-5);
  HyLibLight.Components.CheckValve ChV1(
    pclosed=1e5, 
    popen=1.25e5, 
    diameter=10e-3, 
    volumeA=2.5e-5, 
    volumeB=2.5e-5);
equation 
  connect(Diesel.flange_b, HPV.flange_a);
  connect(HPV.flange_b, CP.flange_a);
  connect(T.port_A, CP.port_A);
  connect(SinWave.outPort, HPV.inPort);
  connect(T.port_A, CP.port_A);
  connect(ChV1.port_B, HPV.port_B);
  connect(ChV2.port_B, HPV.port_A);
  connect(ChV1.port_A, ChV2.port_A);
  connect(CP.port_B, RelCP.port_A);
  connect(RelCP.port_B, T1.port_A);
  connect(RelHP1.port_B, RelHP2.port_B);
  connect(ChV1.port_A, CP.port_B);
  connect(RelHP1.port_A, HMF.port_A);
  connect(RelHP2.port_A, HMF.port_B);
  connect(ChV2.port_B, RelHP2.port_A);
  connect(ChV1.port_B, RelHP1.port_A);
  connect(ChV1.port_A, RelHP1.port_B);
  connect(Constant.outPort, Diesel.inPort);
end ClosedCircuit;