Modelica.Thermal.HeatTransfer.Fahrenheit

Information

The components of this package are provided for the convenience of people working mostly with Fahrenheit units, since all models in package HeatTransfer are based on Kelvin units.

Note, that in package SIunits.Conversions, functions are provided to convert between the units Kelvin, degree Celsius, degree Fahrenheit and degree Rankine. These functions allow, e.g., a direct conversion of units at all places where Kelvin is required as parameter. Example:

    import SIunits.Conversions.*;
    Modelica.Thermal.HeatTransfer.HeatCapacitor C(T0 = from_degF(70));

Modelica.Thermal.HeatTransfer.Fahrenheit.ToKelvin

Information

This component converts all input signals from degree Fahrenheit to Kelvin and provides them as output signals.

Parameters

Name	Default	Description
n	1	Number of inputs (= number of outputs)

Modelica definition

model ToKelvin "Conversion block from °Fahrenheit to Kelvin" 
  parameter Integer n=1 "Number of inputs (= number of outputs)";
  Modelica.Blocks.Interfaces.InPort Fahrenheit(final n=n);
  Modelica.Blocks.Interfaces.OutPort Kelvin(final n=n);
equation 
  Kelvin.signal = from_degF(Fahrenheit.signal);
end ToKelvin;

Modelica.Thermal.HeatTransfer.Fahrenheit.FromKelvin

Information

This component converts all input signals from Kelvin to Fahrenheit and provides them as output signals.

Parameters

Name	Default	Description
n	1	Number of inputs (= number of outputs)

Modelica definition

model FromKelvin "Conversion from Kelvin to °Fahrenheit" 
  parameter Integer n=1 "Number of inputs (= number of outputs)";
  Modelica.Blocks.Interfaces.InPort Kelvin(final n=n);
  Modelica.Blocks.Interfaces.OutPort Fahrenheit(final n=n);
equation 
  Fahrenheit.signal = to_degF(Kelvin.signal);
end FromKelvin;

Modelica.Thermal.HeatTransfer.Fahrenheit.FixedTemperature

Information

This model defines a fixed temperature T at its port in [degF], i.e., it defines a fixed temperature as a boundary condition.

Parameters

Name	Default	Description
T		Fixed Temperature at the port [degF]

Modelica definition

model FixedTemperature 
  "Fixed temperature boundary condition in °Fahrenheit" 
  parameter NonSI.Temperature_degF T "Fixed Temperature at the port";
  Interfaces.HeatPort_b port;
equation 
  port.T = from_degF(T);
end FixedTemperature;

Modelica.Thermal.HeatTransfer.Fahrenheit.PrescribedTemperature

Information

This model represents a variable temperature boundary condition The temperature value in [degF] is given by the input signal to the model. The effect is that an instance of this model acts as an infinite reservoir able to absorb or generate as much energy as required to keep the temperature at the specified value.

Modelica definition

model PrescribedTemperature 
  "Variable temperature boundary condition in °Fahrenheit" 
  
  Interfaces.HeatPort_b port;
  Modelica.Blocks.Interfaces.InPort T(final n=1);
equation 
  port.T = from_degF(T.signal[1]);
end PrescribedTemperature;

Modelica.Thermal.HeatTransfer.Fahrenheit.TemperatureSensor

Information

This is an ideal absolute temperature sensor which returns the temperature of the connected port in Fahrenheit as an output signal. The sensor itself has no thermal interaction with whatever it is connected to. Furthermore, no thermocouple-like lags are associated with this sensor model.

Modelica definition

model TemperatureSensor "Absolute temperature sensor in °Fahrenheit" 
  
  Modelica.Blocks.Interfaces.OutPort T(redeclare type SignalType = NonSI.Temperature_degF);
  Interfaces.HeatPort_a port;
equation 
  T.signal[1] = to_degF(port.T);
  port.Q_dot = 0;
end TemperatureSensor;