; -*- Mode: Jess; mode:font-lock; -*-
;
; Newspaper example for the JessTab Tutorial
;
; This example adds layout rules for updating articles and ads of
; the newspaper kb with references to layout instances.
;
; Author: Henrik Eriksson, Linkoping University
;
; Load this file with (batch "newspaper.jess")
;


(mapclass Content)

(defrule area_r1
  (object (is-a Personals_Ad|Standard_Ad)
          (OBJECT ?a)
          (name ?n)
          (page_number ?p))
 =>
  (assert (page-area ?p Ad ?n "" ?a))
)

(defrule area_r2
  (object (is-a Article)
          (OBJECT ?a)
          (headline ?h)
          (text ?t)
          (page_number ?p))
 =>
  (assert (page-area ?p Article ?h ?t ?a))
)


(defrule size_r1
  (page-area ?p&:(< ?p 10) Article ? ? ?a)
 =>
  (assert (width ?a 100.0))
)


(defrule size_r2
  (page-area ?p&:(>= ?p 10) Article ? ? ?a)
 =>
  (assert (width ?a 50.0))
)


(defrule size_r3
  (page-area ? Article ? ?t ?a)
 =>
  (assert (height ?a (* (str-length ?t) 2.0)))
)


(defrule size_r4
  (page-area ?p Ad ? ? ?a)
 =>
  (assert (width ?a 50.0) (height ?a 50.0))
)


(defrule layout_r1
  (width ?a ?w)
  (height ?a ?h)
 =>
  (slot-set ?a layout (make-instance of Content_Layout
     (main_rectangle (make-instance of Rectangle (width ?w) (height ?h)))))
)